/*[[
	Name := TSD
	Author := Copyright © 2005 Bob O'Brien / Barcode
	Link := 
	Notes := Based on Alexander Elder's Triple Screen system. To be run only on a daily chart.
	Lots := 1.00
	Stop Loss := 0
	Take Profit := 100
	Trailing Stop := 50
]]*/

/////////////////////////////////////////////////////
// Defines
/////////////////////////////////////////////////////
Defines: Slippage(5);			// Slippage
Defines: StopYear(2005);
Defines: MM(0),Leverage(1),AcctSize(10000);

/////////////////////////////////////////////////////
// Variables
/////////////////////////////////////////////////////
var: PriceOpen(0);								// Price Open
var: I(0);										// Misc Counter
Var: NewBar(0),First(True),LotMM(0),LotSize(10000),LotMax(50),vTP(0.00),vSL(0.00),vSTOP(0.00),ModOrder(0);
Var: Direction(0), PosNeg(""), TradesThisSymbol(0),MacdPrevious(0),MacdPrevious2(0),Force(0);
Var: ForcePos(0), ForceNeg(0), NewPrice(0), GlobalName(""),GlobalMacdPrev(""),GlobalMacdPrev2("");
Var: StartMinute1(0),EndMinute1(0),StartMinute2(0),EndMinute2(0),StartMinute3(0),EndMinute3(0);
Var: StartMinute4(0),EndMinute4(0),StartMinute5(0),EndMinute5(0),StartMinute6(0),EndMinute6(0);
var: StartMinute7(0),EndMinute7(0),DummyField(0);


/////////////////////////////////////////////////
//  Initialisation
/////////////////////////////////////////////////
if year < stopyear then exit;
If Curtime - LastTradeTime < 10 then Exit;
If FreeMargin < 500 then Exit;

GlobalName = "Gb1_Wk_"+Symbol+"_Direction";
Direction=GetGlobalVariable(GlobalName);

GlobalMacdPrev = "Gb1_Wk_"+Symbol+"_MacdPrev";
MacdPrevious=GetGlobalVariable(GlobalMacdPrev);

GlobalMacdPrev2 = "Gb1_Wk_"+Symbol+"_MacdPrev2";
MacdPrevious2=GetGlobalVariable(GlobalMacdPrev2);

ForcePos = iForce(2,MODE_EMA,PRICE_CLOSE,1) > 0;
ForceNeg = iForce(2,MODE_EMA,PRICE_CLOSE,1) < 0;
Force = iForce(2,MODE_EMA,PRICE_CLOSE,1);

Comment("TSD for MT3",
        "\n",
        "\n","Weekly OsMAPrevious = ",MacdPrevious,
        "\n","Weekly OsMAPrevious2 = ",MacdPrevious2,
        "\n","Weekly Direction = ",Direction,
        "\n",
        "\n","Daily Force = ",Force,
        "\n","Is Daily Force Bullish = ",ForcePos,
        "\n","Is Daily Force Bearish = ",ForceNeg,
        "\n",
        "\n","vSL = ",vSL, " vTP = ",vTP," vSTOP = ",vSTOP,
        "\n",
        "\n","New Bar Time is ",TimeToStr(newbar),
        "\n",
        "\n","Daily High[1] = ",High[1],
        "\n","Daily High[2] = ",High[2],
        "\n","Daily Low[1] = ",Low[1],
        "\n","Daily Low[2] = ",Low[2],
        "\n",
        "\n","Current Ask Price + 16 pips = ",Ask+(16*Point),
        "\n","Current Bid Price - 16 pips = ",Bid-(16*Point));
        
        

// Check to see if ModifyOrder was successful

If ModOrder == 1 then
{
    Var : PairType(4);
    If Symbol() == "USDJPY" then
    {
    	PairType=2;
    };
	For i=1 to TotalTrades
	{
		If ( (Ord(i,VAL_TYPE) = OP_BUYSTOP) or (Ord(i,VAL_TYPE) = OP_SELLSTOP) ) And OrderValue(i,VAL_SYMBOL) = Symbol Then
		{
			If (NumberToStr(Ord(i,VAL_OPENPRICE),PairType) == NumberToStr(vSTOP,PairType) And NumberToStr(Ord(i,VAL_TAKEPROFIT),PairType) == NumberToStr(vTP,PairType) And NumberToStr(Ord(i,VAL_STOPLOSS),PairType) == NumberToStr(vSL,PairType) ) then
			{
				ModOrder = 0;
			}
			Else
			{
				Alert("Problem modifying order.  Retrying.  Please check logs");
				Print(NumberToStr(Ord(i,VAL_OPENPRICE),PairType)," ",NumberToStr(vSTOP,PairType)," ",NumberToStr(Ord(i,VAL_TAKEPROFIT),PairType)," ",NumberToStr(vTP,PairType)," ",NumberToStr(Ord(i,VAL_STOPLOSS),PairType)," ",NumberToStr(vSL,PairType));
				ModifyOrder(Ord(i,VAL_TICKET),vSTOP,vSL,Ord(i,VAL_TAKEPROFIT),White);
				exit;
			};
		};
	};
};



TradesThisSymbol = 0;
For I = 1 to TotalTrades
{	
	if ord(I, VAL_SYMBOL) == Symbol then TradesThisSymbol ++;
};

// Select a range of minutes in the day to start trading based on the currency pair.
// This is to stop collisions occurring when 2 or more currencies set orders at the same time.
switch Symbol
{
  case "USDCHF":
    StartMinute1 = 0;
	EndMinute1   = 1;
    StartMinute2 = 8;
	EndMinute2   = 9;
    StartMinute3 = 16;
	EndMinute3   = 17;
    StartMinute4 = 24;
	EndMinute4   = 25;
    StartMinute5 = 32;
	EndMinute5   = 33;
    StartMinute6 = 40;
	EndMinute6   = 41;
    StartMinute7 = 48;
	EndMinute7   = 49;
	break;
  case "GBPUSD":
    StartMinute1 = 2;
	EndMinute1   = 3;
    StartMinute2 = 10;
	EndMinute2   = 11;
    StartMinute3 = 18;
	EndMinute3   = 19;
    StartMinute4 = 26;
	EndMinute4   = 27;
    StartMinute5 = 34;
	EndMinute5   = 35;
    StartMinute6 = 42;
	EndMinute6   = 43;
    StartMinute7 = 50;
	EndMinute7   = 51;
	break;
  case "USDJPY":
    StartMinute1 = 4;
	EndMinute1   = 5;
    StartMinute2 = 12;
	EndMinute2   = 13;
    StartMinute3 = 20;
	EndMinute3   = 21;
    StartMinute4 = 28;
	EndMinute4   = 29;
    StartMinute5 = 36;
	EndMinute5   = 37;
    StartMinute6 = 44;
	EndMinute6   = 45;
    StartMinute7 = 52;
	EndMinute7   = 53;
	break;
  case "EURUSD":
    StartMinute1 = 6;
	EndMinute1   = 7;
    StartMinute2 = 14;
	EndMinute2   = 15;
    StartMinute3 = 22;
	EndMinute3   = 23;
    StartMinute4 = 30;
	EndMinute4   = 31;
    StartMinute5 = 38;
	EndMinute5   = 39;
    StartMinute6 = 46;
	EndMinute6   = 47;
    StartMinute7 = 54;
	EndMinute7   = 59;
	break;
};
If (Minute >= StartMinute1 and Minute <= EndMinute1) or
   (Minute >= StartMinute2 and Minute <= EndMinute2) or
   (Minute >= StartMinute3 and Minute <= EndMinute3) or
   (Minute >= StartMinute4 and Minute <= EndMinute4) or
   (Minute >= StartMinute5 and Minute <= EndMinute5) or
   (Minute >= StartMinute6 and Minute <= EndMinute6) or
   (Minute >= StartMinute7 and Minute <= EndMinute7) Then
{
	DummyField = 0; // dummy statement because MT will not allow me to use a continue statement
}
Else Exit;

/////////////////////////////////////////////////
//  Process the next bar details
/////////////////////////////////////////////////
If NewBar != t[0] Then
{
	NewBar = t[0];
	
// Global Variable has a 1 if Weekly MACH is rising and a -1 if Weekly MACD is falling.
	GlobalName = "Gb1_Wk_"+Symbol+"_Direction";
	Direction=GetGlobalVariable(GlobalName);
	
	
	If TradesThisSymbol < 1 Then
	{
/////////////////////////////////////////////////
//  Lot Management
/////////////////////////////////////////////////
		
		If MM < 0 then 
		{
			LotMM = Round(Balance*Leverage/10000)/10;
  			If LotMM > LotMax then LotMM = LotMax;  
	  	};
		If MM = 0 then LotMM = lots;
		if MM > 0 then 
 		{
			LotMM = Round(Balance*Leverage/10000)/10;
 			If LotMM > 1 then LotMM = ceil(LotMM);
 			if LotMM < 1 then LotMM = 1;
	 		If LotMM > LotMax then LotMM = LotMax;  
		};
		
/////////////////////////////////////////////////
//  New Orders Management
/////////////////////////////////////////////////
				
		ForcePos = iForce(2,MODE_EMA,PRICE_CLOSE,1) > 0;
		ForceNeg = iForce(2,MODE_EMA,PRICE_CLOSE,1) < 0;

		If Direction = 1 and ForceNeg then
		{
			PriceOpen = High[1] + 1 * Point;		// Buy 1 point above high of previous candle
			If PriceOpen > (Ask + 16 * Point) Then  // Check if buy price is a least 16 points > Ask
			{
				SetOrder(OP_BUYSTOP,
				LotMM,
				PriceOpen,
				Slippage,
				Low[1] - 1 * Point,
				PriceOpen + TakeProfit * Point,
				BLUE);
				Exit;
			}
			Else
			{
				NewPrice = Ask + 16 * Point;
				SetOrder(OP_BUYSTOP,
				LotMM,
				NewPrice,
				Slippage,
				Low[1] - 1 * Point,
				NewPrice + TakeProfit * Point,
				BLUE);
				Exit;
			};
		};
	
		If Direction = -1 and ForcePos then 
		{
			PriceOpen = Low[1] - 1 * Point;
			If PriceOpen < (Bid - 16 * Point) Then // Check if buy price is a least 16 points < Bid
			{
				SetOrder(OP_SELLSTOP,
				LotMM,
				PriceOpen,
				Slippage,
				High[1] + 1 * Point,
				PriceOpen - TakeProfit * Point,
				RED);
				Exit;
			}
			Else
			{
				NewPrice = Bid - 16 * Point;
				SetOrder(OP_SELLSTOP,
				LotMM,
				NewPrice,
				Slippage,
				High[1] + 1 * Point,
				NewPrice - TakeProfit * Point,
				RED);
				Exit;
			};
		};
	};
	
/////////////////////////////////////////////////
//  Pending Order Management
/////////////////////////////////////////////////
	vSL=0;
	vTP=0;
	vSTOP=0;
	
	
	If TradesThisSymbol > 0 Then
	{
		For i=1 to TotalTrades
		{
			if Ord(i,VAL_TYPE) = OP_BUYSTOP      And
			   OrderValue(i,VAL_SYMBOL) = Symbol Then
			{ 
				if Direction = -1 then 
  				{ 
   			 		DeleteOrder(OrderValue(i,VAL_TICKET),Red); 
	        		Exit; 
				}; 
			};

			if Ord(i,VAL_TYPE) = OP_SELLSTOP     And
			   OrderValue(i,VAL_SYMBOL) = Symbol Then
			{ 
				if Direction = 1 then 
		   	 	{ 
	    			DeleteOrder(OrderValue(i,VAL_TICKET),Red); 
	        		Exit; 
				}; 
			};
			If Ord(i,VAL_TYPE) = OP_BUYSTOP      And
			   OrderValue(i,VAL_SYMBOL) = Symbol Then
		    {
				If High[1] < High[2] Then
	  			{ 
	  				ModOrder = 1;

					If High[1] > (Ask + 16 * Point) Then
					{ 
						vSL=Low[1] - 1 * Point;
						vTP=Ord(i,VAL_TAKEPROFIT);
						vSTOP=High[1] + 1 * Point;
		   				ModifyOrder(Ord(i,VAL_TICKET),
	    				High[1] + 1 * Point,
		 				Low[1] - 1 * Point,
	      				Ord(i,VAL_TAKEPROFIT),
						White);
						Exit;
					}
					Else
					{
						vSL=Low[1] - 1 * Point;
						vTP=Ord(i,VAL_TAKEPROFIT);
						vSTOP=Ask + 16 * Point;
						ModifyOrder(Ord(i,VAL_TICKET),
	    				Ask + 16 * Point,
	    	 			Low[1] - 1 * Point,
		      			Ord(i,VAL_TAKEPROFIT),
						White);
						Exit;
					};
				};
			};
	
			If Ord(i,VAL_TYPE) = OP_SELLSTOP     And
			   OrderValue(i,VAL_SYMBOL) = Symbol Then
			{
				If Low[1] > Low[2] Then
				{ 
					ModOrder = 1;

					If Low[1] < (Bid - 16 * Point) Then
					{
						vSL=High[1] + 1 * Point;
						vTP=Ord(i,VAL_TAKEPROFIT);
						vSTOP=Low[1] - 1 * Point;
	   					ModifyOrder(Ord(i,VAL_TICKET),
	    				Low[1] - 1 * Point, 
	     				High[1] + 1 * Point,
		      			Ord(i,VAL_TAKEPROFIT),
		       			Gold);
	    	   			Exit;
					}
					Else
					{
						vSL=High[1] + 1 * Point;
						vTP=Ord(i,VAL_TAKEPROFIT);
						vSTOP=Bid - 16 * Point;
						ModifyOrder(Ord(i,VAL_TICKET),
	    				Bid - 16 * Point, 
	     				High[1] + 1 * Point,
	      				Ord(i,VAL_TAKEPROFIT),
	       				Gold);
		       			Exit;
					};
				};
			};
		};
	};	
};

/////////////////////////////////////////////////
//  Stop Loss Management
/////////////////////////////////////////////////

If TradesThisSymbol > 0 Then
	{
	For i=1 to TotalTrades
	{
		If Ord(i,VAL_TYPE) = OP_BUY          And
		   OrderValue(i,VAL_SYMBOL) = Symbol Then
    	{
			If (Ask-Ord(i,VAL_OPENPRICE)) > (TrailingStop * Point) Then
  			{ 
				If Ord(i,VAL_STOPLOSS) < (Ask - TrailingStop * Point) Then
				{ 
	   				ModifyOrder(Ord(i,VAL_TICKET),
    				Ord(i,VAL_OPENPRICE),
     				Ask - TrailingStop * Point,
      				Ask + TakeProfit * Point,
					White);
					Exit;
				};
			};
		};
	
		If Ord(i,VAL_TYPE) = OP_SELL         And
		   OrderValue(i,VAL_SYMBOL) = Symbol Then
		{
			If (Ord(i,VAL_OPENPRICE) - Bid) > (TrailingStop * Point) Then
			{ 
				If Ord(i,VAL_STOPLOSS) > (Bid + TrailingStop * Point) Then
				{ 
   					ModifyOrder(Ord(i,VAL_TICKET),
    				Ord(i,VAL_OPENPRICE), 
	     			Bid + TrailingStop * Point,
    	  			Bid - TakeProfit * Point,
       				Gold);
       				Exit;
				};
			};
		};
	};	
};