/*[[
	Name := Killer - iM2M3 M15
	Author := Copyright © 2004, KillerKhan
	Link := http://www.iamatyourmuthazhouse.com/
	Separate Window := No
	First Color := Aqua
	First Draw Type := Line
	First Symbol := 217
	Use Second Data := Yes
	Second Color := Fuchsia
	Second Draw Type := Line
	Second Symbol := 218
]]*/

var: i(0);
var: vBeginBar(1000);
var: vPrevDay(0);
var: vCurDay(0);
var: vDayHigh(0);
var: vDayLow(0);
var: vYesterDayHigh(0);
var: vYesterDayLow(0);
var: vYesterDayClose(0);
var: P(0),S1(0),R1(0),M2(0),M3(0);

for i = bars downto 0
{
	SetIndexValue(i, 0);
	SetIndexValue2(i, 0);
};

if Period != 15 then
{
	Comment("Custom Indicator 'Killer - iM2M3 M15' is for M15 Charts Only");
	exit;
};

for i = vBeginBar downto 0
{
	vCurDay = TimeDay(time[i]);
	
	if vPrevDay != vCurDay then
	{
		vYesterDayClose = CLOSE[i+1];
		vYesterDayHigh = vDayHigh;
		vYesterDayLow = vDayLow;

		P = (vYesterDayHigh + vYesterDayLow + vYesterDayClose) / 3;
		
		R1 = (P * 2) - vYesterDayLow;
		S1 = (P * 2) - vYesterDayHigh;
		
		M2 = (P + S1) / 2;
		M3 = (P + R1) / 2;
				
		vDayHigh = HIGH[i];
		vDayLow  = LOW[i];
		
		vPrevDay = vCurDay;
	};

	vDayHigh = max(vDayHigh, HIGH[i]);
	vDayLow = min(vDayLow, LOW[i]);
	
	SetIndexValue(i, M3);
	SetIndexValue2(i, M2);
};