/*[[
	Name := CoeffOfLine
	Author := Copyright © 2004, Rosh, fixes by Nick Bilak
	Link := http://www.metaquotes.net/
	Notes := Вычисляет наклон линии через метод наименьшего квадратичного отклонения
	Separate Window := Yes
	First Color := White
	First Draw Type := Line
	First Symbol := 217
	Use Second Data := Yes
	Second Color := DimGray
	Second Draw Type := Line
	Second Symbol := 218
]]*/
// Вычисляем для функции Y=A*X+B  коэффициент А для цен и значений индикаторов
// Считаем значения Х=1,2,3,4,5 . Константу B  не вычисляем, так как не имеет смысла. B=(T-A*M)/, где n=5
// T=Сумма Yi, M=Сумма Xi, N=Сумма Xi*Xi, Z=Сумма Xi*Yi
// A=(T+(N-2*Z)*n/M)/M 
// Вычисляем отношение Aцен/Aиндикатора
Inputs: BeginBars(2000),ndot(5),HiTrigger(0.5),LoTrigger(-0.5);
Variable : LoopBegin(0),shift(0),cnt(0),TYVar(0),ZYVar(0),TIndicatorVar(0),ZIndicatorVar(0),M(0),N(0),AY(0),AIndicator(0);
var: prevbars(0),is_First(False),ival(0);


SetLoopCount(0);

// Check for additional bars loading or total reloadng.
If Bars<prevbars or Bars-prevbars>1 Then is_First=True;
prevbars=Bars;
//--------------------------------------------------------

// Pre-Loop setup
// loopbegin prevents counting of previously plotted bars excluding current Bars
if is_First Then Begin
   if bars<BeginBars then LoopBegin=bars-ndot-2 else LoopBegin=BeginBars-ndot-2;
   is_First=False;
End;
//--------------------------------------------------------

loopBegin=loopBegin+1; // Plot the current bar also

// loop from first bar to current bar (with shift=0)
For shift=loopBegin Downto 0 Begin
	TYVar=0;
	ZYVar=0;
	N=0;
	M=0;
	TIndicatorVar=0;
	ZIndicatorVar=0;
	For cnt=1 To ndot Begin // n=5 -  по пяти точкам
		ZYVar=ZYVar+(H[shift+cnt-1]+L[shift+cnt-1])/2*(6-cnt);
		TYVar=TYVar+(H[shift+cnt-1]+L[shift+cnt-1])/2;
		N=N+cnt*cnt; //равно 55
		M=M+cnt; //равно 15
		ZIndicatorVar=ZIndicatorVar+iMAEx(5,MODE_SMMA,3,PRICE_MEDIAN,shift+cnt-1)*(6-cnt);
		TIndicatorVar=TIndicatorVar+iMAEx(5,MODE_SMMA,3,PRICE_MEDIAN,shift+cnt-1);
	End;
	AY=(TYVar+(N-2*ZYVar)*ndot/M)/M;
	AIndicator=(TIndicatorVar+(N-2*ZIndicatorVar)*ndot/M)/M;
	ival=(-1000)*Log(AY/AIndicator);
	SetIndexValue(shift, ival);
   // Plot dual-value Trigger Line
   If Ival>0 then
      SetIndexValue2(shift,HiTrigger)
   Else
      SetIndexValue2(shift,LoTrigger);
   loopBegin=loopBegin-1;   // Prevent repeating previously plotted bars on next tick
End;